;NPC Release 1 (2003) By Geoff
;99% Translated NPCs Including Quests

[@main]
I can take you to the marriage area. Before I do I need\
to know why you are going and some proof.\ \
<Getting Married/@jhdl1>\
<Attending Ceremony/@cjhl>\
<Demands Invitation/@syqj>\
<Close/@exit>

; Getting Married Enter Script Start
[@jhdl1]
#IF 
check [588] 0
; If Hasn't arranged wedding 
#SAY 
You need to have sorted some marriage resistration\
before you get married. Go and see the LoveCompany\
in Bichon Wall and they will help you.\ \
<Ok/@exit>
#ELSESAY 
If you are getting married you need the marriage\
certificate and the assembly hall admission. I need\
to inspect these items.\ \
<Allow inspection/@jhdl2>\
<Close/@exit>

[@jhdl2]
#IF
check [589] 1
#SAY
Hey I remember you <$USERNAME>, you are already\
married. Go away!\ \
<Ok/@exit>
#ELSEACT 
goto @jhdl3

[@jhdl3]
#IF
check [588] 1
checkitem WeddCert(M) 1
checkitem WeddAdmisn 1
#SAY 
I wish you good luck with your wedding. You may\
now enter\ \
<Enter/@jhdl4>\
<Close/@exit>
#ELSEACT
goto @jhdl3-2

[@jhdl3-2]
#IF
check [588] 1
checkitem WeddCert(F) 1
checkitem WeddAdmisn 1
#SAY 
I wish you good luck with your wedding. You may\
now enter\ \
<Enter/@jhdl4>\
<Close/@exit>
#ELSESAY
You don't have the items you need. Go and\
get them and come back.\ \
<Ok/@exit>

[@jhdl4]
#ACT
set [589] 1
take WeddAdmisn 1
mapmove g002 37 43
; Getting Married Enter Script End

; Guest Enter Script Start
[@cjhl]
Hello, marriage is a very sacred thing. I can only let you in\
if you have an invitation. Do you have one?\ \
<Yes/@cjhl1>\
<No/@exit>

[@cjhl1]
#IF
checkitem invitation 1
#ACT
take invitation 1
mapmove g002 37 43
#ELSESAY
Sorry, but you do not have a wedding invitation. I cannot\
let you in without one.\ \
<Ok/@exit>
; Guest Enter Script End

; Demand Invitation Script Start
[@syqj]
#IF 
; If before this person enters the ceremony conference site
check [589] 1
#SAY
Sorry, the invitation already sent. I also did not look\
for one invitation again, regret!\ \
<Close/@exit>
#ELSEACT
goto @syqj1

[@syqj1]
#IF
check [588] 0
#SAY
Only the people who are getting married can give\
out invitations. I am very sorry.\ \
<Ok/@exit>

#ELSESAY
<Receive invitation/@syqj2>

[@syqj2]
#ACT
give invitation 1